struct++🔗ℹ

1 Introduction🔗ℹ

struct-plus-plus provides extended syntax for creating structs. It does not support supertypes or field options (#:auto and #:mutable). Aside from that, it’s a drop-in replacement for the normal struct form. So long as your struct does not have a supertype or a field marked #:auto or #:mutable, you can literally just change struct to struct++ and your code will continue to work as before but you will now have a keyword constructor, functional setters and updaters for all fields, and reflection data. (NOTE: See the ‘Reflection’ section below for how to handle structs with #:prefab.)

struct-plus-plus offers the following benefits over normal struct:

• keyword constructor

• (optional) functional setters and updaters for each field

• (optional) distinct defaults for individual fields

• (optional) contracts for each field

• (optional) dotted accessors to clarify struct/field relationship

• (optional) wrapper functions for each field

• (optional) wrappers around field accessors

• (optional) dependency checking between fields

• (optional) declarative syntax for business logic rules

• (optional) declarative syntax for converting the structures to arbitrary other values

• (optional) declarative syntax for generating the struct type from other values

• (optional) easy run-time introspection and reflection

2 Design Goal🔗ℹ

The intent is to move structs from being dumb data repositories into being data models in the sense of MVC programming. They should contain data that is internally consistent and valid according to business rules. This centralizes the checks that would otherwise need to be done at the point of use.

3 Synopsis🔗ℹ

> (require json struct-plus-plus)

; Declare a new struct type

> (struct++ plant1 (genus) #:transparent)

;  ; create an instance in various ways

> (plant1 'Rosa) ; normal Racket struct usage

(plant1 'Rosa)

> (plant1++ #:genus 'Rosa)  ; struct-plus-plus keyword constructor

(plant1 'Rosa)

> (hash->struct++ plant1++ (hash 'genus 'Rosa)) ; create from hash

(plant1 'Rosa)

;  ; cf dotted accessors, functional setters and updaters

> (define p1 (plant1++ #:genus 'Rosa))

> (plant1.genus p1) ; plant1.genus is equivalent to plant1-genus

'Rosa

> (set-plant1-genus p1 "Helianthus") ; functional setter

(plant1 "Helianthus")

> (update-plant1-genus p1 (lambda (type) (~a type ", subtype 10"))) ; functional updater

(plant1 "Rosa, subtype 10")

;  ; Let's enforce data types. Genus names must be strings

> (struct++ plant2 ([genus string?]) #:transparent)

> (plant2 'Rosa) ; basic Racket constructor will generate a non-compliant instance

(plant2 'Rosa)

; The keyword constructor raises an error on non-compliant data

> (plant2++ #:genus 'Rosa)

plant2++: contract violation

expected: string?

given: 'Rosa

in: the #:genus argument of

(-> #:genus string? plant2?)

contract from: (function plant2++)

blaming: program

(assuming the contract is correct)

> (plant2++ #:genus "Rosa")

(plant2 "Rosa")

> (hash->struct++ plant2++ (hash 'genus "Rosa"))

(plant2 "Rosa")

;  ; Additionally, let's force scientifically-accurate case onto the genus.

> (struct++ plant3 ([genus string?])     (#:rule ("genus names are required to be lowercase with initial capital" #:transform genus (genus) [(string-titlecase genus)]))     #:transparent)

> (plant3++ #:genus "rosa")

(plant3 "Rosa")

;  ; Same as the above but using a wrapper function instead of a transform rule

> (struct++ plant3 ([genus string? string-titlecase]) #:transparent)

> (plant3++ #:genus "rosa")

(plant3 "Rosa")

;  ; Time to go hard. Let's make a struct that describes a person who wants to join the military, even if that requires lying.

> (define (get-min-age) 18.0)

> (struct++ recruit             ([name (or/c symbol? non-empty-string?) ~a] ; Accepts either, forces to string              [age positive?]              [(eyes 'brown) (or/c 'brown 'black 'green 'blue 'hazel)] ; Defaults to 'brown if not specified              [(height-m #f) (between/c 0 3)]  ; Defaults to #f which is not a valid value but if it wasn't provided then the transform rules below will auto-calculate it              [(weight-kg #f) positive?]              [(bmi #f) positive?]              [(felonies 0) natural-number/c])                (#:rule ("bmi can be found" #:at-least    2         (height-m weight-kg bmi))              #:rule ("ensure height-m"  #:transform   height-m  (height-m weight-kg bmi) [(or height-m (sqrt (/ weight-kg bmi)))])              #:rule ("ensure weight-kg" #:transform   weight-kg (height-m weight-kg bmi) [(or weight-kg (* (expt height-m 2) bmi))])              #:rule ("ensure bmi"       #:transform   bmi       (height-m weight-kg bmi) [(or bmi (/ 100 (expt height-m 2)))])              #:rule ("lie about age"    #:transform   age       (age) [(define min-age (get-min-age))                                                                        (cond [(>= age 18) age]                                                                              [else min-age])])              #:rule ("eligible-for-military?" #:check (age felonies bmi) [(and (>= age 18)                                                                                (= 0 felonies)                                                                                (<= 25 bmi))])              #:make-dotted-accessors? #t ; This is the default. Use #f to not generate dotted accessors              #:make-setters? #t ; This is the default. Use #f to not generate functional setters and updaters              ; create several functions that marshal the struct for different purposes              #:convert-for (db (#:remove '(eyes bmi) ; Prep the struct for writing to a DB                                 #:rename (hash 'height-m 'height 'weight-kg 'weight)))              #:convert-for (alist (#:remove '(bmi eyes)                                    #:rename (hash 'height-m 'height 'weight-kg 'weight)                                    #:post hash->list))              #:convert-for (json (#:action-order '(rename remove add overwrite)                                   #:post  write-json                                   #:rename (hash 'height-m 'height 'weight-kg 'weight)                                   #:remove '(felonies)                                   #:add (hash 'vision "20/20")                                   #:overwrite (hash 'hair "brown"  ; overwrite value                                                     'shirt (thunk "t-shirt") ; use the result of the thunk as the value for 'shirt                                                     'eyes symbol->string ; one-argument function so run the current value through and use the result                                                     'age (lambda (age) (* 365 age)) ; same, except the function is custom                                                     'vision (lambda (h key val) ; three-argument function so pass the hash, the key, and the current value and use the result                                                               (if (> (hash-ref h 'age) 30)                                                                   "20/15"                                                                   val))))))                #:transparent)

;  ; keyword constructor exists and requires several fields

> (recruit++ #:name 'tom)

application: required keyword argument not supplied

procedure: recruit++

required keyword: #:age

arguments...:

#:name 'tom

> (define bob     (recruit++ #:name 'bob                #:age 16 ; Bob isn't old enough for the military so he will lie and say he's 18                #:height-m 2                #:weight-kg 100))

; Note that Bob's name is now a string, his age was changed, his BMI was calculated, and his felonies defaulted to 0

> bob

(recruit "bob" 18.0 'brown 2 100 25 0)

;  ; side-by-side of the dotted accessors and standard accessors to show equivalence

> (list (recruit.name bob) (recruit-name bob))

'("bob" "bob")

> (list (recruit.age bob) (recruit-age bob))

'(18.0 18.0)

;  ; various conversion functions that marshal to different forms

> (recruit->db bob)

'#hash((weight . 100) (felonies . 0) (height . 2) (name . "bob") (age . 18.0))

;  deprecated alias for the above

> (recruit/convert->db bob)

'#hash((weight . 100) (felonies . 0) (height . 2) (name . "bob") (age . 18.0))

> (recruit->alist bob)

'((weight . 100) (felonies . 0) (height . 2) (name . "bob") (age . 18.0))

;  deprecated alias for the above

> (recruit/convert->alist bob)

'((weight . 100) (felonies . 0) (height . 2) (name . "bob") (age . 18.0))

4 Syntax🔗ℹ

Note: Supertypes are not supported as of this writing, nor are field-specific keywords (#:mutable and #:auto). See below for why.

Note: Rules can be specified using either multiple #:rule clauses or a single #:rules clause that will be unpacked to be the equivalent set of #:rule clauses. In both cases the syntax of the clauses is exactly the same, so it’s mostly an aesthetic preference. Regardless, it’s better to choose one method and use it consistently. See Warnings for details.

5 Constructors🔗ℹ

After you have used (struct++ recruit ...) to generate a recruit type, there are three ways to create an instance of that type:

• recruit++

• (hash->struct++ recruit++ h)

• recruit

In most cases the one you want will be recruit++. It uses keywords, checks the field contracts, executes business logic as defined in rules, etc.

The hash->struct++ function will accept a function and a hash where the keys are symbols matching the name of the fields in a struct++ declaration. A new instance of the struct type will be created using the specified function with the hash keys used as keyword arguments. Assuming you are passing one of the struct-plus-plus keyword constructor functions this means that field contracts will be checked, wrappers applied, etc.

The recruit constructor is the standard one that Racket generates from the (struct ...) declaration. Using it will allow you to create structures that are invalid under the field contracts. See below:

> (require struct-plus-plus)

> (struct++ flower ([genus string?][color symbol?]) #:transparent)

;  ; struct-plus-plus keyword constructor

> (flower++ #:genus "Rosa" #:color 'red)

(flower "Rosa" 'red)

;  ; convert from a hash via the struct-plus-plus keyword constructor

> (hash->struct++  flower++ (hash 'genus "Heliantus" 'color 'yellow))

(flower "Heliantus" 'yellow)

;  ; keyword constructor chokes on data that violates field contracts

> (flower++ #:genus 184 #:color #f)

flower++: contract violation

expected: symbol?

given: #f

in: the #:color argument of

(-> #:color symbol? #:genus string? flower?)

contract from: (function flower++)

blaming: program

(assuming the contract is correct)

;  ; ditto when used through hash->struct++

> (hash->struct++  flower++ (hash 'genus 998 'color 17))

flower++: contract violation

expected: symbol?

given: 17

in: the #:color argument of

(-> #:color symbol? #:genus string? flower?)

contract from: (function flower++)

blaming: program

(assuming the contract is correct)

;  ; constructor function given to `hash->struct++` is assumed to be a keyword function, so don't do this:

> (hash->struct++  flower (hash 'genus 998 'color 17))

application: procedure does not accept keyword arguments

procedure: flower

arguments...:

#:color 17

#:genus 998

;  ; default Racket constructor does not check field constraints

> (flower 184 #f)

(flower 184 #f)

6 Wrappers🔗ℹ

All fields have wrappers; either you set one or the wrapper is identity. Values go through the wrapper whenever the struct is created or when a setter/updater is called. The return value of the wrapper is what is actually stored in the struct.

7 Dotted Accessors🔗ℹ

7.1 Basics🔗ℹ

Racket’s default accessor construction can be confusing. For example:

(remote-server-send-ch foo)

Is that retrieving the value of the server-send-ch field in the remote struct, or is it retrieving the value of the send-ch field in the remote-server struct?

Compare the less ambiguous version:

(remote-server.send-ch foo)

When #:make-dotted-accessors? is missing or has the value #t, struct++ will generate a dotted accessor for each field. When #:make-dotted-accessors? is defined and has the value #f the dotted accessors will not be generated.

7.2 Access Wrappers🔗ℹ

Accessor wrappers allow you to make the struct do something extra when retrieving a field’s value, such as retrieve the data from a database, log the act of accessing, etc.

Access wrappers only work through the dotted accessors, not through the default accessors created by struct. This is a feature, not a bug.

Accessor wrappers take two arguments: the struct itself and the current value of the field.

> (struct++ dog ([name (or/c string? promise?) #:wrap-accessor (λ (the-struct current-val) (force current-val))]))

> (define fido (dog++ #:name (lazy "fido")))

> (displayln   (~a " default accessor returns: " (dog-name fido)       "\n before dotted accessor, promise was forced?: " (promise-forced? (dog-name fido))       "\n dotted accessor returns: " (dog.name fido)       "\n after dotted accessor, promise was forced?: " (promise-forced? (dog-name fido))))

default accessor returns: #<promise!fido>  before dotted accessor, promise was forced?: #f  dotted accessor returns: fido  after dotted accessor, promise was forced?: #t

That lambda is ugly and a lot of the time we don’t want to use the struct argument, only the current value. How about something prettier? The wrap-accessor macro consumes a function and returns another function that takes any number of arguments and passes all but the first argument to the wrapped function. (i.e., it will create a function that accepts both the struct and the value as arguments and then ignore the struct and passes the value to the wrapped function)

> (struct++ horse ([name (or/c string? promise?) #:wrap-accessor (wrap-accessor force)]))

> (define secretariat (horse++ #:name (lazy "secretariat")))

> (displayln   (~a " default accessor returns: " (horse-name secretariat)       "\n before dotted accessor, promise was forced?: " (promise-forced? (horse-name secretariat))       "\n dotted accessor returns: " (horse.name secretariat)       "\n after dotted accessor, promise was forced?: " (promise-forced? (horse-name secretariat))))

default accessor returns: #<promise!secretariat>  before dotted accessor, promise was forced?: #f  dotted accessor returns: secretariat  after dotted accessor, promise was forced?: #t

Note: One drawback to accessor wrappers is that they do not actually alter the value stored in the struct, they only return something different. That means that using something like match will pull out the value actually stored there, not the value that would have come from the accessor wrapper.

As an example of why you might want to use accessor wrappers, they would be an excellent way to implement an ORM, where a struct represents a database and performs queries when you access various fields. Using setters and updaters could then be used to write to the database.

8 Setters and Updaters🔗ℹ

When #:make-setters? is missing or has the value #t, struct++ will generate a functional setter and updater for each field. When #:make-setters? is defined and has the value #f the setters and updaters will not be generated.

Given a struct of type recruit with a field age, the name of the setter will be set-recruit-age and the updater will be update-recruit-age. Setters receive a value, updaters receive a one-argument function that receives the current value and returns the new value.

The setters and updaters are not exported. You will need to put them in the provide line manually.

9 Rules🔗ℹ

Structs always have business logic associated with them – that’s the entire point. Much of that can be embodied as contracts or wrapper functions, but if you want to enforce requirements between fields then you need rules. No one wants to code all that stuff manually, so let’s have some delicious syntactic sugar that lets us create them declaratively.

struct-plus-plus supports three types of rules, all of which are run when a struct instance is created:

• #:check, which verifies that a condition holds and uses raise-arguments-exception if it does not.

• #:at-least, which verifies that at least N of a particular set of arguments meet a particular requirement (by default ‘are not #f’), thereby enabling the rest to be calculated.

• #:transform, which alters one or more arguments before the instance is constructed. This might be used to calculate an argument value or to compel certain constraints to be maintained. Rules are evaluated in order and later rules will see the transformed values of earlier rules.

Let’s go back to our example of the recruit. In order to be accepted into the military, you must be at least 18 years of age, have no felonies on your record, and be reasonably fit (BMI no more than 25).

Bob really wants to join the military, and he’s willing to lie about his age to do that. The following struct checks that enough information is available to calculate Bob’s BMI (body mass index) and then populates his height, weight, and BMI.

> (define (get-min-age) 18.0)

> (struct++ lying-recruit             ([name (or/c symbol? non-empty-string?) ~a]              [age positive?]              [(height-m #f) (between/c 0 3)]              [(weight-kg #f) positive?]              [(bmi #f) positive?]              [(felonies 0) natural-number/c])        (#:rule ("bmi can be found"     #:at-least    2       (height-m weight-kg bmi))         #:rule ("lie about age if necessary" #:transform age (age) [(if (>= age (get-min-age)) age (get-min-age))])         #:rule ("ensure height/weight/BMI"     #:transform                                                   (height-m weight-kg bmi)                                                   (bmi height-m weight-kg name)                                                   ["fields to transform and fields to use can differ in number and order"                                                    "values returned must match values to transform in number and order"                                                    (values                                                     (or height-m  (sqrt (/ weight-kg bmi)))                                                     (or weight-kg (* (expt height-m 2) bmi))                                                     (or bmi       (/ 100 (expt height-m 2))))]))           #:transparent)

In the "ensure height/weight/BMI" rule it is not necessary to check that you have enough information to do the calculations because the "bmi can be found" rule has already established that either two or three out of the three values (height-m, weight-kg, bmi) were specified.

> (define bob     (lying-recruit++ #:name 'bob                      #:age 16                      #:height-m 2                      #:weight-kg 100))

> bob

(lying-recruit "bob" 18.0 2 100 25 0)

Note that Bob’s name has been changed from a symbol to a string as per Army regulation 162.11a, his age has magically changed from 16 to 18.0, and his BMI has been calculated. Suppose we try to invalidate these constraints?

> (set-lying-recruit-felonies bob #f)

set-lying-recruit-felonies: contract violation

expected: natural-number/c

given: #f

in: the 2nd argument of

(->

lying-recruit?

natural-number/c

lying-recruit?)

contract from:

(function set-lying-recruit-felonies)

blaming: program

(assuming the contract is correct)

Nope! You cannot invalidate the structure by way of the functional setters/updaters, although you could do it if you marked your struct as #:mutable and then used the standard Racket mutators. (e.g. set-recruit-felonies!)

There are two separate but equivalent formats for declaring rules: the #:rule keyword followed by a rule clause or the #:rules keyword following by a parenthesized sequence of rule clauses. The #:rules parenthesized form is more Racketish, whereas the #:rule syntax exists for historical reasons and is maintained for backwards compatibility. Still, it’s mostly an aesthetic choice and they can be intermixed.

> (struct++ animal             ([name (or/c symbol? non-empty-string?) ~a]              [age integer?])             (              #:rules (["pointlessly check name" #:check (name)        [#t]]                       ["have a birthday"        #:transform age (age) [(add1 age)]])              #:rule ("name is >= 2 characters " #:check (name) [(>= (string-length (~a name)) 2)])              #:rules (["pointlessly check age"  #:check (age) [#t]]))                #:transparent)

> (animal++ #:name 'fido #:age 0)

(animal "fido" 1)

(NOTE: Although you *can* intermix #:rule and #:rules, you probably shouldn’t, as changes caused by transform rules in a #:rules clause are not visible in a later #:rule clause. This is a bug and will be fixed eventually.)

10 Converters🔗ℹ

10.1 convert-for🔗ℹ

10.1.1 Summary🔗ℹ

When marshalling a struct for writing to a database, a file, etc, it is useful to turn it into a different data structure, usually but not always a hash. Converters will change the struct into a hash, then pass the hash to the hash-remap function in handy, allowing you to return anything you want. hash-remap takes a series of keyword arguments specifying how the hash should be mangled. Specifically:

• #:remove <list> : delete the keys in the list from the hash

• #:overwrite <hash> : change the values of existing keys or add missing ones

• #:add <hash> : add one or more keys to the hash, die if they were already there

• #:rename <hash> : change the names of one or more keys

• #:value-is-default? <function> : a predicate that specifies what values should be defaulted

• #:default <hash> : if a key is not there, add it. If it is there it will be set if and only if it matches the value-is-default? predicate.

• #:action-order <list> : specify in what order to apply the above options. Default is ’(include remove overwrite add rename default)

• #:post <function> : run the resulting hash through a function that returns anything you want

Note that #:overwrite provides special behavior for values that are procedures with arity 0, 1, or 3. The values used are the result of calling the procedure with no args (arity 0); the current value (arity 1); or hash, key, current value (arity 3).

Note that #:default provides special behavior for values that are procedures. If the procedure has arity of exactly 2 then it will be called as (func key hash). Procedures with other arity will be called as (func key). The value used for the field is comes back from the procedure call.

10.1.2 convert-for Examples🔗ℹ

convert-for functions are named <struct-name>-><purpose>, where ‘purpose’ is the name given to the conversion specification. (DEPRECATED: There are also aliases named <struct-name>/convert-><purpose>) For example:

> (struct++ person             (name age)             (#:convert-for (db (#:remove '(age)))              #:convert-for (json (#:add (hash 'created-at (current-seconds))                                   #:post write-json)))             #:transparent)

> (define bob (person "bob" 18))

> (person->db   bob)

'#hash((name . "bob"))

> (person->json bob)

{"age":18,"created-at":1707314850,"name":"bob"}

;  ; deprecated aliases for the above

> (person/convert->db   bob)

'#hash((name . "bob"))

> (person/convert->json bob)

{"age":18,"created-at":1707314850,"name":"bob"}

;  ; examples that demonstrate hash-mangling options

> (struct++ fruit       (name color price)       (       #:convert-for (include (#:include '(name))) ; include only the name field       #:convert-for (remove (#:remove '(name price))) ; remove everything but the color field       #:convert-for (add-good (#:add (hash 'type "added the 'type' key")))       #:convert-for (add-bad (#:add (hash 'name "Boom! can't 'add' existing keys and 'name' key is already there")))       #:convert-for (rename (#:rename (hash 'price 'price-in-pennies)))       #:convert-for (overwrite-name-via-value (#:overwrite (hash 'name "yummy fruit!")))       #:convert-for (overwrite-name-via-func-arity0 (#:overwrite (hash 'name (thunk "value from thunk"))))       #:convert-for (overwrite-name-via-func-arity1 (#:overwrite (hash 'name (lambda (v) (~a "the original value was: '" v "'")))))       #:convert-for (overwrite-name-via-func-arity3 (#:overwrite (hash 'name (lambda (h k v) (list h k v)))))       #:convert-for (convert-using-all-options          (#:action-order '(add default rename remove overwrite) ; specify the order in which to apply the options           #:add (hash 'subtype "honeycrisp"  ; add new keys                       'source "Vermont"                       'organic? 'unspecified                       'leaves 2)           #:value-is-default? 'unspecified ; keys with a value of 'unspecified will be defaulted, along with keys that are not present           #:default (hash 'source-farm "McDonald's"  ; key isn't there so it will be added                           'organic? #t ; will replace existing value because existing value is considered default                           'leaves (lambda (k h) (add1 (hash-ref h k))))           #:rename (hash 'price "price-in-pennies" ; rename the pre-existing 'price key                          'subtype 'breed) ; rename the 'subtype' key that was created in the 'add' step above           #:remove '(price-in-pennies no-such-key) ; ensure key is not present. doesn't care if it wasn't           #:overwrite (hash 'name "a new name"                             'color (thunk "a value made inside a thunk") ; function of 0 args is called                             'breed string-titlecase ; function of 1 argument receives the value                             'multi-leaved? (lambda (h k v) ; add new key. function of 3 arguments gets hash, key, value                             (>= (hash-ref h 'leaves) 2)))           #:post hash->list ; after all earlier changes are made, convert the hash to a list))))

> (define apple (fruit "apple" "red" 199))

> (fruit->include apple)

'#hash((name . "apple"))

> (fruit->remove apple)

'#hash((color . "red"))

> (fruit->add-good apple)

'#hash((color . "red") (name . "apple") (type . "added the 'type' key") (price . 199))

> (fruit->add-bad apple)

hash-remap: add-hash cannot include keys that are already in

the hash (hint: use #:default, or #:overwrite, or use

#:action-order to put 'remove before 'add)

add-hash: '#hash((name . "Boom! can't 'add' existing keys

and 'name' key is already there"))

hash to add to (remove and overwrite already done):

'#hash((color . "red") (name . "apple") (price . 199))

> (fruit->rename apple)

'#hash((color . "red") (name . "apple") (price-in-pennies . 199))

> (fruit->overwrite-name-via-value apple)

'#hash((color . "red") (name . "yummy fruit!") (price . 199))

> (fruit->overwrite-name-via-func-arity0 apple)

'#hash((color . "red") (name . "value from thunk") (price . 199))

> (fruit->overwrite-name-via-func-arity1 apple)

'#hash((color . "red") (name . "the original value was: 'apple'") (price . 199))

> (pretty-print (fruit->overwrite-name-via-func-arity3 apple))

'#hash((color . "red")        (name         .         (#hash((color . "red") (name . "apple") (price . 199)) name "apple"))        (price . 199))

> (pretty-print (fruit->convert-using-all-options apple))

'((organic? . #t)   (source . "Vermont")   (breed . "Honeycrisp")   (leaves . 2)   (color . "a value made inside a thunk")   ("price-in-pennies" . 199)   (name . "a new name")   (source-farm . "McDonald's")   (multi-leaved? . #t))

10.2 convert-from🔗ℹ

convert-from functions go the opposite direction from convert-for – they accept an arbitrary value and they turn it into a struct.

convert-from functions are named <source>-><struct-name>++, where ‘source’ is the name given to the conversion specification. For example:

> (require struct-plus-plus)

> (struct++ key ([data bytes?]) #:transparent)

> (struct++ person             ([id exact-positive-integer?]              [name non-empty-string?]              [(keys '()) list?])                (#:convert-from (vector (vector?                                      (vector id                                              (app (compose (curry map key) vector->list) keys)                                              name)                                      (id keys name))))                #:transparent)

> (vector->person++ (vector 9 (vector #"foo" #"bar") "fred"))

(person 9 "fred" (list (key #"foo") (key #"bar")))

There are four parts to the convert-from clause:

1. The name of what is being converted. In the example this is vector. It is used to generate the name of the converter function, e.g. vector->person++

2. A predicate that will recognize that thing (e.g. vector?), which is used to build the contract for the converter function

3. A match clause that will parse the thing and assign its elements to identifiers that correspond to the field names of the struct

4. A series of the identifiers from the match clause that should be used to construct the struct. Again, the identifiers must have the same names as the fields; this is so that the macro can use the identifiers to generate the correct keywords for the constructor

In this example we created a function named vector->person++ which takes a vector of three elements and returns a person struct. The first element of the vector must be an exact-positive-integer?, the second must be a vector containing zero or more byte strings, and the third must be a non-empty-string?. The vector of bytes is converted to a list, the elements of which are converted to key structs.

Behind the scenes, the #:convert-from specification above is equivalent to the following:

> (require struct-plus-plus)

> (struct++ key ([data bytes?]) #:transparent)

> (struct++ person             ([id         exact-positive-integer?]              [name       non-empty-string?]              [(keys '()) list?])              #:transparent)

> (define/contract (vector->person++ val)     (-> vector? person?)     (match val       [(vector id                (app (compose (curry map key) vector->list) keys)                name)        (person++ #:id id #:keys keys #:name name)]))

> (vector->person++ (vector 9 (vector #"foo" #"bar") "fred"))

(person 9 "fred" (list (key #"foo") (key #"bar")))

11 Reflection🔗ℹ

By default, all struct++ types support reflection by way of a structure property, ‘prop:struct++’, which contains a promise (via delay) which contains a struct++-info struct containing relevant metadata.

Use the #:omit-reflection keyword to disable this behavior. You will need to do so if you are including the #:prefab struct option.

Relevant struct definitions:

> (struct++ person ([name (or/c symbol? string?) ~a]                     [(age 18) number?]                     [eyes])             (#:rule ("name ok" #:check (name) [(> (string-length name) 3)])              #:rule ("is >= teen" #:check (age) [(>= age 13)])              #:convert-for (db (#:add (hash 'STRUCT-TYPE 'person))))             #:transparent)

> (define bob (person 'bob 18 'brown))

> (struct++-ref bob)

#<promise!#<struct++-info>>

> (force (struct++-ref bob))

#<struct++-info>

Declarations for the various types used in reflection:

(struct struct++-rule (name type))

;  contracts: string? (or/c 'transform 'check 'at-least)

;  e.g.: "name ok" 'check

(struct struct++-field (name accessor contract wrapper default))

;  e.g.: 'name (or/c symbol? string?) ~a 'no-default-given

;  e.g.: 'age number? identity 18

(struct struct++-info

(base-constructor constructor predicate fields rules converters))

;  base-constructor will be the ctor defined by struct, e.g. 'person'

;  constructor will be the ctor defined by struct++, e.g. 'person++'

;  predicate will be, e.g., 'person?'

;  converters will be a list of the procedures defined by the #:convert-for items

> (match (force (struct++-ref bob))     [(struct* struct++-info               ([base-constructor base-constructor]                [constructor constructor]                [predicate predicate]                [fields (and fields                             (list (struct* struct++-field                                            ([name     field-names]                                             [accessor field-accessors]                                             [contract field-contracts]                                             [wrapper  field-wrappers]                                             [default  field-defaults]))                                   ...))]                [rules (and rules                            (list (struct* struct++-rule                                           ([name rule-names]                                            [type rule-types]))                                  ...))]                [converters converters]))         (pretty-print       (hash 'field-names     field-names             'field-accessors field-accessors             'field-contracts field-contracts             'field-wrappers  field-wrappers             'field-defaults  field-defaults             'rule-names      rule-names             'rule-types      rule-types             'converters      converters             'fields          fields             'rules           rules))])

'#hash((converters . (#<procedure:person->db>))        (field-accessors         .         (#<procedure:person-name>          #<procedure:person-age>          #<procedure:person-eyes>))        (field-contracts         .         (#<flat-contract: (or/c symbol? string?)>          #<procedure:number?>          #<flat-contract: any/c>))        (field-defaults . (no-default-given 18 no-default-given))        (field-names . (name age eyes))        (field-wrappers         .         (#<procedure:~a> #<procedure:identity> #<procedure:identity>))        (fields . (#<struct++-field> #<struct++-field> #<struct++-field>))        (rule-names . ("name ok" "is >= teen"))        (rule-types . (check check))        (rules . (#<struct++-rule> #<struct++-rule>)))

12 API🔗ℹ

12.1 Utilities🔗ℹ

Helpful tip: Under normal circumstances, a ‘structure-type transformer binding’ has the same name as the struct type.

> (struct person (name age hair) #:transparent)

> (define bob (person 'bob 18 "brown"))

> bob

(person 'bob 18 "brown")

> (struct->hash person bob)

'#hash((hair . "brown") (name . bob) (age . 18))

> (define acc-wrap (wrap-accessor force))

> acc-wrap

#<procedure:acc-wrap>

; `acc-wrap' is equivalent to (lambda args (apply force (cdr args)))

12.2 Reflection Implementation🔗ℹ

See Reflection for full details on how to use reflection.

13 Warnings, Notes, and TODOs🔗ℹ

Some of these were already mentioned above:

13.1 Warnings🔗ℹ

• One drawback to accessor wrappers is that they do not actually alter the value stored in the struct, they only return something different. That means that using something like match will pull out the value actually stored there, not the value that would have come from the accessor wrapper.

• TO FIX: Changes caused by transform rules in a #:rules clause are not visible in a later #:rule clause.

• If you include the #:prefab option then you must also include #:omit-reflection

• As with any function in Racket, default values are not sent through the contract. Therefore, if you declare a field such as (e.g.) [(userid #f) integer?] but you don’t pass a value to it during construction then you will have an invalid value (#f in a slot that requires an integer). Default values ARE sent through wrapper functions, so be sure to take that into account – if you have a default value of #f and a wrapper function of add1 then you are setting yourself up for failure.

• In a convert-from clause, the match clause must bind components to identifiers that will be used to construct the struct. Those identifiers must have the same names as the fields so that the code can correctly generate the keywords for those fields.

13.2 Notes🔗ℹ

• recruit++ checks contracts and rules etc. recruit does not

• person.name respects the accessor wrapper, person-name does not

• #:transform rules take 1+ expressions in their code segment. The return value becomes the new value of the target

• #:check rules take exactly one expression in their code segment. If the returned value is true then the rule passed, and if it’s #f then the rule calls raise-arguments-error

• Rules are processed in order. Changes made by a #:transform rule will be seen by later rules

• None of the generated functions (struct-name++, set-struct-name-field-name, etc) are exported. You’ll need to list them in your provide line manually

• See the hash-remap function in the handy module for details on what the #:convert-for converter options mean

13.3 TODOs🔗ℹ

• TODO: Add more complex variations of #:at-least, such as: #:at-least 1 (person-id (person-name department-id))

• TODO: add a keyword that will control generation of mutation setters that respect contracts and rules. (Obviously, only if you’ve made your struct #:mutable)

13.4 Field options and why they aren’t available🔗ℹ

Field options (#:auto and #:mutable) are not supported and there are no plans to support them in the future.

Regarding #:auto: The per-field default syntax that struct++ provides is strictly superior to #:auto, so there is no need to provide it. Furthermore, auto fields come with the restriction that they cannot have values provided at construction time – it’s not a default, it’s a "here’s this field that is automagically generated and you can’t do anything but read it". This would substantially complicate generating the keyword constructor, since the macro would need to locate all fields that were auto and then exclude them from the constructor. Furthermore, it wouldn’t be sensible for an auto field to have a default value, contract, wrapper, or functional setter, so there would need to be an entirely separate field syntax and then many additional checks. The costs of supporting #:auto far outweigh the marginal value.

Regarding #:mutable: Supporting this one would be straightforward, so not supporting it is a deliberate choice. The functional setters that struct++ provides should satisfy nearly all the same use cases as the #:mutable field option, and it’s still possible to use the struct-level #:mutable option if you really want to mutate. Mutation should be avoided in general, so leaving out the #:mutable field option seems like a good decision.

13.5 Supertypes and why they aren’t available🔗ℹ

tl;dr: It’s probably doable but it was more complex than I wanted to put the work in for. Pull requests welcome.

Supertypes in Racket come with some tricky issues, such as this:

> (struct animal (name age) #:transparent)

> (struct person animal (name job)  #:transparent)

;  Note that both animal and person have a name field

;

> (define bob (person 'human 27 'bob 'teacher))

> bob

(person 'human 27 'bob 'teacher)

> (person? bob)

#t

> (animal? bob)

#t

> (person-name bob)

'bob

> (animal-name bob)

'human

> (struct->hash person bob)

'#hash((animal-name . human) (job . teacher) (name . bob) (animal-age . 27))

The supertype and the subtype have fields with the same name. When you access fields from the animal part of the struct, you do it using animal- functions, thereby losing the association to the person type. What should the setter and updater look like? How do you ensure that the wrapper function and field contracts from the supertype are respected by the subtype?

This would be possible to do using reflection data, but that data isn’t available when #:omit-reflection is set, which is necessary if the struct is #:prefab. I would prefer to not need to have a note saying "this works, unless you have #:omit-reflection set".

14 Thanks🔗ℹ

The words ‘shoulders of giants’ apply here. I would like to offer great thanks to:

• Greg Hendershott, for his "Fear of Macros" essay

• Alexis King (aka lexi-lambda), for teaching me a lot about macros on the racket-users list (especially this post) and providing the struct-update module (docs, code) which gave me a lot of inspiration

• Ryan Culpepper, who was generous enough to sit with me at RacketCon8 and walk me through proper use of syntax classes

• The members of the community for being so helpful on the racket-users list

And, as always, to the dev team who produced and maintain Racket. You guys rule and we wouldn’t be here without you.